打开电脑，进入Windows操作系统，在资源管理器的左边栏中清楚地显示了系统管理的所有磁盘的信息以及各个磁盘所容纳的文件与文件夹(如图一)。这种常见的显示方式是由一个根节点和若干个子节点构成的，这被称为“树形结构”。这种树形结构的用途非常广泛，在很多常用软件中都出现过它的身影。Windows中将这种结构封装为“树形控件”，即TreeView控件，它与ListView、Button等一样都属于系统自带的通用公共控件。在Delphi中，TreeView也被封装成了VCL组件，它的位置在“Win32组件”面板上，是我们最常用的几个组件之一。
Delphi自带的TreeView组件可以显示树形结构，也可以为每个节点指定不同的图标来区分各自的功能。但在平时的使用中，我们发现它并不能嵌入CheckBox或者是RadioButton组件，这样用户就不能直观地选择某一部分节点或某个节点。如何来解决这个问题呢？我们思考之后发现，有两种思路可以完成前面所述的任务。一种是在TreeView组件的基础上继承的它的功能，并添加所要的功能（使TreeView能嵌入CheckBox或者是RadioButton组件）即重写一个组件。另一种是利用用户的错觉，将CheckBox或者是RadioButton所能实现的外观用两种状态的图片（一种是选中状态另一种是未选中状态）来交替显示，走迂回路线来完成任务。我们来分析一下这两种方法的优缺点：第一种方法要重写一个组件，显然难度较大，所用时间较长；第二种方法，利用TreeView组件本身就具备的显示图标功能，简便易行，所用时间短，能够完成需求。比较之后，我们选择作用第二种方法，先来看一下完成之后的效果(如图二)，应该说是达到了目的，现在我们来细述一下完成的过程：
首先，我们在Win32面板上选择ImageList组件，设置它的StateImages属性，包括两种状态的图标，一种是选中状态，另一种是未先中状态。
其次，我们调用ToggleTreeView过程(实现方法见后文)，实现在鼠标单击和键盘选择的状态下改变状态图标的功能。
ToggleTreeView过程实现代码如下：
procedure ToggleTreeViewCheckBoxes(
Node :TTreeNode;
cUnChecked, //CheckBox未选中状态
cChecked, //CheckBox选中状态
cRadioUnchecked, //RadioButtion未选中状态
cRadioChecked :integer); // RadioButtion选中状态
var
tmp:TTreeNode;
begin
if Assigned(Node) then
begin
//如果当前是未选中状态则变为选中状态
if Node.StateIndex = cUnChecked then
Node.StateIndex := cChecked
//如果当前是选中状态则变为未选中状态
else if Node.StateIndex = cChecked then
Node.StateIndex := cUnChecked
else if Node.StateIndex = cRadioUnChecked then
begin
tmp := Node.Parent;
if not Assigned(tmp) then
tmp := TTreeView(Node.TreeView).Items.getFirstNode
else
tmp := tmp.getFirstChild;
while Assigned(tmp) do
begin
if (tmp.StateIndex in
[cRadioUnChecked,cRadioChecked]) then
tmp.StateIndex := cRadioUnChecked;
tmp := tmp.getNextSibling;
end;
Node.StateIndex := cRadioChecked;
end; // if StateIndex = cRadioUnChecked
end; // if Assigned(Node)
end;
第三，上面的代码解决的是状态图标转换的问题，那如何解决在鼠标单击和键盘选择之后就改变状态呢？下面给出实现代码：
(1)当鼠标单击时，代码如下：
procedure TForm1.TreeView1Click(Sender: TObject);
var
P:TPoint;
begin
GetCursorPos(P); //得到光标的位置
P := TreeView1.ScreenToClient(P);
if (htOnStateIcon in
TreeView1.GetHitTestInfoAt(P.X,P.Y)) then
ToggleTreeViewCheckBoxes(
TreeView1.Selected,
cFlatUnCheck,
cFlatChecked,
cFlatRadioUnCheck,
cFlatRadioChecked);
end;
(2)当键盘选择时，代码如下：
procedure TForm1.TreeView1KeyDown(
Sender: TObject;
var Key: Word;
Shift: TShiftState);
begin
if (Key = VK_SPACE) and
Assigned(TreeView1.Selected) then
ToggleTreeViewCheckBoxes(
TreeView1.Selected,
cFlatUnCheck,
cFlatChecked,
cFlatRadioUnCheck,
cFlatRadioChecked);
end;
最后，我们给出一个小例子，来验证一下的我们试验的结果。在窗体上的摆放TreeView、ImageList、Button和一个Memo组件(如图三)，在加入上面的代码之后，我们来编写这个Button的单击事件的代码：
procedure TForm1.Button1Click(Sender: TObject);
var
BoolResult:boolean;
tn : TTreeNode;
begin
if Assigned(TreeView1.Selected) then
begin
tn := TreeView1.Selected;
BoolResult := tn.StateIndex in
[cFlatChecked,cFlatRadioChecked];
Memo1.Text := tn.Text +
#13#10 +
'Selected: ' +
BoolToStr(BoolResult, True);
//Memo给出所选中的节点和当前的状态
end;
end;
因为篇幅所限，上面的例子给出是最简单的一个情况，如果要编写更为专业的软件，请读者朋友充分发挥想象，一定做出更好的效果(如图四)。
